/* arch/m68knommu/platform/68EZ328/ads_flash.ld
 * 
 * Copyright (C) 1999  Vladimir Gurevich <vgurevic@cisco.com>
 *                     Bear & Hare Software, Inc.
 *
 * Based on: arch/m68knommu/platform/68EZ328/ucsimm.ld
 */

MEMORY 
	{
	ramvec : ORIGIN = 0x00000000, LENGTH = 0x400
	dram   : ORIGIN = 0x00000400, LENGTH = 0x800000 - 0x400
	eram   : ORIGIN = 0x00800000, LENGTH = 1
	romvec : ORIGIN = 0x10000000, LENGTH = 0x400
	flash  : ORIGIN = 0x10000400, LENGTH = 0x400000 - 0x400
	eflash : ORIGIN = 0x10400000, LENGTH = 1
	}

SECTIONS
{
	.ramvec :
	{
	_ramvec = . ;
		*(.ramvec)
	} > ramvec
	
	.data : AT(_etext)
	{
	. = ALIGN(0x10) ;
	_sdata = . ;
	__data_start = . ;

	. = ALIGN(0x4) ;
		*(.rodata)
	. = ALIGN(0x4) ;
		*(.data)
	. = ALIGN(0x4) ;
		*(.data.*)	

	. = ALIGN(0x4) ;
	__setup_start = .;
		*(.setup.init)
	. = ALIGN(0x4) ;
	__setup_end = .;

	. = ALIGN(0x4) ;
	__initcall_start = .;
		*(.initcall.init)
	. = ALIGN(0x4) ;
	__initcall_end = .;

	. = ALIGN(0x2000) ;
		*(.data.init_task)
	. = ALIGN(0x2000) ;

	_edata = ALIGN(0x10) ;
        } > dram
        
          .bss :
        {
	. = ALIGN(0x10) ;
	_sbss = . ;
	__bss_start = ALIGN(0x10) ;
	__data_end = ALIGN(0x10) ;
		*(.bss)
		*(COMMON)
	. = ALIGN(0x10) ;
	_ebss = . ;
	_end = ALIGN(0x10) ;
	end = ALIGN(0x10) ;
	} > dram
	
	.eram :
	{
		_boot_stack = . - 4;
		_ramend = . ;
	} > eram

	/*
	 * FLASH portion
	 */
	.romvec :
	{
		_flashstart = . ;
		_romvec = . ;
		*(.romvec)
	} > romvec

        .text :
	{
	_stext = . ;
        	*(.text)
	. = ALIGN(0x4) ;
		*(.text.*)
	. = ALIGN(0x4) ;
		*(.exitcall.exit)
	. = ALIGN(0x4) ;
	_etext = . ;
	__data_rom_start = ALIGN(0x4);
        } > flash
        
	.eflash :
	{
	_flashend = . ;
	} > eflash
}